[关闭]
@cyysu 2017-10-12T10:19:14.000000Z 字数 11685 阅读 932

Bat-实战基础篇（四）

  • 时间：2017年10月12日
  • 作者：Kali
  • 邮箱：cyysu.github.io@gmail.com/2869905223@qq.com/微信lwyx1413
  • 版本：4.0
  • 描述：批处理实战基础篇四，主要讲解tomcat下启动脚本，本文主要讲解catalina.bat这个脚本

Bat系列教程

项目实战

其目录下面的脚本文件如下，有些重复的内容，这里不做过多介绍，有遇到什么不会的内容可以查看Bat系列教程

下面我们一一来分析其里面的内容，为了避免文本过长，每个文件单独一篇文章讲解。

  1. # catalina.bat
  2. :: 我们重点讲解bat语法以及模仿别人如何编写，从他人代码中丰富自己，不对脚本中的逻辑关系进行过多介绍。
  3. @echo off
  4. rem Licensed to the Apache Software Foundation (ASF) under one or more
  5. rem contributor license agreements.  See the NOTICE file distributed with
  6. rem this work for additional information regarding copyright ownership.
  7. rem The ASF licenses this file to You under the Apache License, Version 2.0
  8. rem (the "License"); you may not use this file except in compliance with
  9. rem the License.  You may obtain a copy of the License at
  10. rem
  11. rem     http://www.apache.org/licenses/LICENSE-2.0
  12. rem
  13. rem Unless required by applicable law or agreed to in writing, software
  14. rem distributed under the License is distributed on an "AS IS" BASIS,
  15. rem WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  16. rem See the License for the specific language governing permissions and
  17. rem limitations under the License.
  19. rem ---------------------------------------------------------------------------
  20. rem Start/Stop Script for the CATALINA Server
  21. rem
  22. rem Environment Variable Prerequisites
  23. rem
  24. rem   Do not set the variables in this script. Instead put them into a script
  25. rem   setenv.bat in CATALINA_BASE/bin to keep your customizations separate.
  26. rem
  27. rem   WHEN RUNNING TOMCAT AS A WINDOWS SERVICE:
  28. rem   Note that the environment variables that affect the behavior of this
  29. rem   script will have no effect at all on Windows Services. As such, any
  30. rem   local customizations made in a CATALINA_BASE/bin/setenv.bat script
  31. rem   will also have no effect on Tomcat when launched as a Windows Service.
  32. rem   The configuration that controls Windows Services is stored in the Windows
  33. rem   Registry, and is most conveniently maintained using the "tomcatXw.exe"
  34. rem   maintenance utility, where "X" is the major version of Tomcat you are
  35. rem   running.
  36. rem
  37. rem   CATALINA_HOME   May point at your Catalina "build" directory.
  38. rem
  39. rem   CATALINA_BASE   (Optional) Base directory for resolving dynamic portions
  40. rem                   of a Catalina installation.  If not present, resolves to
  41. rem                   the same directory that CATALINA_HOME points to.
  42. rem
  43. rem   CATALINA_OPTS   (Optional) Java runtime options used when the "start",
  44. rem                   "run" or "debug" command is executed.
  45. rem                   Include here and not in JAVA_OPTS all options, that should
  46. rem                   only be used by Tomcat itself, not by the stop process,
  47. rem                   the version command etc.
  48. rem                   Examples are heap size, GC logging, JMX ports etc.
  49. rem
  50. rem   CATALINA_TMPDIR (Optional) Directory path location of temporary directory
  51. rem                   the JVM should use (java.io.tmpdir).  Defaults to
  52. rem                   %CATALINA_BASE%\temp.
  53. rem
  54. rem   JAVA_HOME       Must point at your Java Development Kit installation.
  55. rem                   Required to run the with the "debug" argument.
  56. rem
  57. rem   JRE_HOME        Must point at your Java Runtime installation.
  58. rem                   Defaults to JAVA_HOME if empty. If JRE_HOME and JAVA_HOME
  59. rem                   are both set, JRE_HOME is used.
  60. rem
  61. rem   JAVA_OPTS       (Optional) Java runtime options used when any command
  62. rem                   is executed.
  63. rem                   Include here and not in CATALINA_OPTS all options, that
  64. rem                   should be used by Tomcat and also by the stop process,
  65. rem                   the version command etc.
  66. rem                   Most options should go into CATALINA_OPTS.
  67. rem
  68. rem   JAVA_ENDORSED_DIRS (Optional) Lists of of semi-colon separated directories
  69. rem                   containing some jars in order to allow replacement of APIs
  70. rem                   created outside of the JCP (i.e. DOM and SAX from W3C).
  71. rem                   It can also be used to update the XML parser implementation.
  72. rem                   Defaults to $CATALINA_HOME/endorsed.
  73. rem
  74. rem   JPDA_TRANSPORT  (Optional) JPDA transport used when the "jpda start"
  75. rem                   command is executed. The default is "dt_socket".
  76. rem
  77. rem   JPDA_ADDRESS    (Optional) Java runtime options used when the "jpda start"
  78. rem                   command is executed. The default is 8000.
  79. rem
  80. rem   JPDA_SUSPEND    (Optional) Java runtime options used when the "jpda start"
  81. rem                   command is executed. Specifies whether JVM should suspend
  82. rem                   execution immediately after startup. Default is "n".
  83. rem
  84. rem   JPDA_OPTS       (Optional) Java runtime options used when the "jpda start"
  85. rem                   command is executed. If used, JPDA_TRANSPORT, JPDA_ADDRESS,
  86. rem                   and JPDA_SUSPEND are ignored. Thus, all required jpda
  87. rem                   options MUST be specified. The default is:
  88. rem
  89. rem                   -agentlib:jdwp=transport=%JPDA_TRANSPORT%,
  90. rem                       address=%JPDA_ADDRESS%,server=y,suspend=%JPDA_SUSPEND%
  91. rem
  92. rem   JSSE_OPTS       (Optional) Java runtime options used to control the TLS
  93. rem                   implementation when JSSE is used. Default is:
  94. rem                   "-Djdk.tls.ephemeralDHKeySize=2048"
  95. rem
  96. rem   LOGGING_CONFIG  (Optional) Override Tomcat's logging config file
  97. rem                   Example (all one line)
  98. rem                   set LOGGING_CONFIG="-Djava.util.logging.config.file=%CATALINA_BASE%\conf\logging.properties"
  99. rem
  100. rem   LOGGING_MANAGER (Optional) Override Tomcat's logging manager
  101. rem                   Example (all one line)
  102. rem                   set LOGGING_MANAGER="-Djava.util.logging.manager=org.apache.juli.ClassLoaderLogManager"
  103. rem
  104. rem   TITLE           (Optional) Specify the title of Tomcat window. The default
  105. rem                   TITLE is Tomcat if it's not specified.
  106. rem                   Example (all one line)
  107. rem                   set TITLE=Tomcat.Cluster#1.Server#1 [%DATE% %TIME%]
  108. rem ---------------------------------------------------------------------------
  110. setlocal
  112. :: 第一段
  113. rem Suppress Terminate batch job on CTRL+C
  114. if not ""%1"" == ""run"" goto mainEntry
  115. if "%TEMP%" == "" goto mainEntry
  116. if exist "%TEMP%\%~nx0.run" goto mainEntry
  117. :: %~nx0表示文件的名字  不带路径
  118. echo Y>"%TEMP%\%~nx0.run"
  119. :: 如果%TEMP%\catalina.bat.run 不存在 那么就跳转mainEntry
  120. if not exist "%TEMP%\%~nx0.run" goto mainEntry
  121. echo Y>"%TEMP%\%~nx0.Y"
  122. :: %~f0表示运行的文件全路径  %*代表所有参数
  123. call "%~f0" %* <"%TEMP%\%~nx0.Y"
  124. rem Use provided errorlevel
  125. set RETVAL=%ERRORLEVEL%
  126. del /Q "%TEMP%\%~nx0.Y" >NUL 2>&1
  127. exit /B %RETVAL%
  128. :mainEntry
  129. del /Q "%TEMP%\%~nx0.run" >NUL 2>&1
  131. :: 第二段
  132. rem Guess CATALINA_HOME if not defined
  133. set "CURRENT_DIR=%cd%"
  134. if not "%CATALINA_HOME%" == "" goto gotHome
  135. set "CATALINA_HOME=%CURRENT_DIR%"
  136. if exist "%CATALINA_HOME%\bin\catalina.bat" goto okHome
  137. cd ..
  138. set "CATALINA_HOME=%cd%"
  139. cd "%CURRENT_DIR%"
  140. :gotHome
  142. if exist "%CATALINA_HOME%\bin\catalina.bat" goto okHome
  143. echo The CATALINA_HOME environment variable is not defined correctly
  144. echo This environment variable is needed to run this program
  145. goto end
  146. :okHome
  148. rem Copy CATALINA_BASE from CATALINA_HOME if not defined
  149. if not "%CATALINA_BASE%" == "" goto gotBase
  150. set "CATALINA_BASE=%CATALINA_HOME%"
  151. :gotBase
  153. rem Ensure that any user defined CLASSPATH variables are not used on startup,
  154. rem but allow them to be specified in setenv.bat, in rare case when it is needed.
  155. set CLASSPATH=
  157. rem Get standard environment variables
  158. if not exist "%CATALINA_BASE%\bin\setenv.bat" goto checkSetenvHome
  159. call "%CATALINA_BASE%\bin\setenv.bat"
  160. goto setenvDone
  161. :checkSetenvHome
  162. if exist "%CATALINA_HOME%\bin\setenv.bat" call "%CATALINA_HOME%\bin\setenv.bat"
  163. :setenvDone
  165. rem Get standard Java environment variables
  166. if exist "%CATALINA_HOME%\bin\setclasspath.bat" goto okSetclasspath
  167. echo Cannot find "%CATALINA_HOME%\bin\setclasspath.bat"
  168. echo This file is needed to run this program
  169. goto end
  170. :okSetclasspath
  171. call "%CATALINA_HOME%\bin\setclasspath.bat" %1
  172. :: 这个格式是if的特殊用法 if 检测执行是否正确，同时if还可以检测变量是否定义 采用 if defined 
  173. if errorlevel 1 goto end
  175. rem Add on extra jar file to CLASSPATH
  176. rem Note that there are no quotes as we do not want to introduce random
  177. rem quotes into the CLASSPATH
  178. if "%CLASSPATH%" == "" goto emptyClasspath
  179. set "CLASSPATH=%CLASSPATH%;"
  180. :emptyClasspath
  181. set "CLASSPATH=%CLASSPATH%%CATALINA_HOME%\bin\bootstrap.jar"
  183. if not "%CATALINA_TMPDIR%" == "" goto gotTmpdir
  184. set "CATALINA_TMPDIR=%CATALINA_BASE%\temp"
  185. :gotTmpdir
  187. rem Add tomcat-juli.jar to classpath
  188. rem tomcat-juli.jar can be over-ridden per instance
  189. if not exist "%CATALINA_BASE%\bin\tomcat-juli.jar" goto juliClasspathHome
  190. set "CLASSPATH=%CLASSPATH%;%CATALINA_BASE%\bin\tomcat-juli.jar"
  191. goto juliClasspathDone
  192. :juliClasspathHome
  193. set "CLASSPATH=%CLASSPATH%;%CATALINA_HOME%\bin\tomcat-juli.jar"
  194. :juliClasspathDone
  196. if not "%JSSE_OPTS%" == "" goto gotJsseOpts
  197. set JSSE_OPTS="-Djdk.tls.ephemeralDHKeySize=2048"
  198. :gotJsseOpts
  199. set "JAVA_OPTS=%JAVA_OPTS% %JSSE_OPTS%"
  201. if not "%LOGGING_CONFIG%" == "" goto noJuliConfig
  202. set LOGGING_CONFIG=-Dnop
  203. if not exist "%CATALINA_BASE%\conf\logging.properties" goto noJuliConfig
  204. set LOGGING_CONFIG=-Djava.util.logging.config.file="%CATALINA_BASE%\conf\logging.properties"
  205. :noJuliConfig
  207. if not "%LOGGING_MANAGER%" == "" goto noJuliManager
  208. set LOGGING_MANAGER=-Djava.util.logging.manager=org.apache.juli.ClassLoaderLogManager
  209. :noJuliManager
  211. rem ----- Execute The Requested Command ---------------------------------------
  213. echo Using CATALINA_BASE:   "%CATALINA_BASE%"
  214. echo Using CATALINA_HOME:   "%CATALINA_HOME%"
  215. echo Using CATALINA_TMPDIR: "%CATALINA_TMPDIR%"
  216. if ""%1"" == ""debug"" goto use_jdk
  217. echo Using JRE_HOME:        "%JRE_HOME%"
  218. goto java_dir_displayed
  219. :use_jdk
  220. echo Using JAVA_HOME:       "%JAVA_HOME%"
  221. :java_dir_displayed
  222. echo Using CLASSPATH:       "%CLASSPATH%"
  224. set _EXECJAVA=%_RUNJAVA%
  225. set MAINCLASS=org.apache.catalina.startup.Bootstrap
  226. set ACTION=start
  227. set SECURITY_POLICY_FILE=
  228. set DEBUG_OPTS=
  229. set JPDA=
  231. if not ""%1"" == ""jpda"" goto noJpda
  232. set JPDA=jpda
  233. if not "%JPDA_TRANSPORT%" == "" goto gotJpdaTransport
  234. set JPDA_TRANSPORT=dt_socket
  235. :gotJpdaTransport
  236. if not "%JPDA_ADDRESS%" == "" goto gotJpdaAddress
  237. set JPDA_ADDRESS=8000
  238. :gotJpdaAddress
  239. if not "%JPDA_SUSPEND%" == "" goto gotJpdaSuspend
  240. set JPDA_SUSPEND=n
  241. :gotJpdaSuspend
  242. if not "%JPDA_OPTS%" == "" goto gotJpdaOpts
  243. set JPDA_OPTS=-agentlib:jdwp=transport=%JPDA_TRANSPORT%,address=%JPDA_ADDRESS%,server=y,suspend=%JPDA_SUSPEND%
  244. :gotJpdaOpts
  245. shift
  246. :noJpda
  248. if ""%1"" == ""debug"" goto doDebug
  249. if ""%1"" == ""run"" goto doRun
  250. if ""%1"" == ""start"" goto doStart
  251. if ""%1"" == ""stop"" goto doStop
  252. if ""%1"" == ""configtest"" goto doConfigTest
  253. if ""%1"" == ""version"" goto doVersion
  255. echo Usage:  catalina ( commands ... )
  256. echo commands:
  257. echo   debug             Start Catalina in a debugger
  258. echo   debug -security   Debug Catalina with a security manager
  259. echo   jpda start        Start Catalina under JPDA debugger
  260. echo   run               Start Catalina in the current window
  261. echo   run -security     Start in the current window with security manager
  262. echo   start             Start Catalina in a separate window
  263. echo   start -security   Start in a separate window with security manager
  264. echo   stop              Stop Catalina
  265. echo   configtest        Run a basic syntax check on server.xml
  266. echo   version           What version of tomcat are you running?
  267. goto end
  269. :doDebug
  270. shift
  271. set _EXECJAVA=%_RUNJDB%
  272. set DEBUG_OPTS=-sourcepath "%CATALINA_HOME%\..\..\java"
  273. if not ""%1"" == ""-security"" goto execCmd
  274. shift
  275. echo Using Security Manager
  276. set "SECURITY_POLICY_FILE=%CATALINA_BASE%\conf\catalina.policy"
  277. goto execCmd
  279. :doRun
  280. shift
  281. if not ""%1"" == ""-security"" goto execCmd
  282. shift
  283. echo Using Security Manager
  284. set "SECURITY_POLICY_FILE=%CATALINA_BASE%\conf\catalina.policy"
  285. goto execCmd
  287. :doStart
  288. shift
  289. if "%TITLE%" == "" set TITLE=Tomcat
  290. set _EXECJAVA=start "%TITLE%" %_RUNJAVA%
  291. if not ""%1"" == ""-security"" goto execCmd
  292. shift
  293. echo Using Security Manager
  294. set "SECURITY_POLICY_FILE=%CATALINA_BASE%\conf\catalina.policy"
  295. goto execCmd
  297. :doStop
  298. shift
  299. set ACTION=stop
  300. set CATALINA_OPTS=
  301. goto execCmd
  303. :doConfigTest
  304. shift
  305. set ACTION=configtest
  306. set CATALINA_OPTS=
  307. goto execCmd
  309. :doVersion
  310. %_EXECJAVA% -classpath "%CATALINA_HOME%\lib\catalina.jar" org.apache.catalina.util.ServerInfo
  311. goto end
  314. :execCmd
  315. rem Get remaining unshifted command line arguments and save them in the
  316. set CMD_LINE_ARGS=
  317. :setArgs
  318. if ""%1""=="""" goto doneSetArgs
  319. set CMD_LINE_ARGS=%CMD_LINE_ARGS% %1
  320. shift
  321. goto setArgs
  322. :doneSetArgs
  324. rem Execute Java with the applicable properties
  325. if not "%JPDA%" == "" goto doJpda
  326. if not "%SECURITY_POLICY_FILE%" == "" goto doSecurity
  327. %_EXECJAVA% %LOGGING_CONFIG% %LOGGING_MANAGER% %JAVA_OPTS% %CATALINA_OPTS% %DEBUG_OPTS% -Djava.endorsed.dirs="%JAVA_ENDORSED_DIRS%" -classpath "%CLASSPATH%" -Dcatalina.base="%CATALINA_BASE%" -Dcatalina.home="%CATALINA_HOME%" -Djava.io.tmpdir="%CATALINA_TMPDIR%" %MAINCLASS% %CMD_LINE_ARGS% %ACTION%
  328. goto end
  329. :doSecurity
  330. %_EXECJAVA% %LOGGING_CONFIG% %LOGGING_MANAGER% %JAVA_OPTS% %CATALINA_OPTS% %DEBUG_OPTS% -Djava.endorsed.dirs="%JAVA_ENDORSED_DIRS%" -classpath "%CLASSPATH%" -Djava.security.manager -Djava.security.policy=="%SECURITY_POLICY_FILE%" -Dcatalina.base="%CATALINA_BASE%" -Dcatalina.home="%CATALINA_HOME%" -Djava.io.tmpdir="%CATALINA_TMPDIR%" %MAINCLASS% %CMD_LINE_ARGS% %ACTION%
  331. goto end
  332. :doJpda
  333. if not "%SECURITY_POLICY_FILE%" == "" goto doSecurityJpda
  334. %_EXECJAVA% %LOGGING_CONFIG% %LOGGING_MANAGER% %JAVA_OPTS% %JPDA_OPTS% %CATALINA_OPTS% %DEBUG_OPTS% -Djava.endorsed.dirs="%JAVA_ENDORSED_DIRS%" -classpath "%CLASSPATH%" -Dcatalina.base="%CATALINA_BASE%" -Dcatalina.home="%CATALINA_HOME%" -Djava.io.tmpdir="%CATALINA_TMPDIR%" %MAINCLASS% %CMD_LINE_ARGS% %ACTION%
  335. goto end
  336. :doSecurityJpda
  337. %_EXECJAVA% %LOGGING_CONFIG% %LOGGING_MANAGER% %JAVA_OPTS% %JPDA_OPTS% %CATALINA_OPTS% %DEBUG_OPTS% -Djava.endorsed.dirs="%JAVA_ENDORSED_DIRS%" -classpath "%CLASSPATH%" -Djava.security.manager -Djava.security.policy=="%SECURITY_POLICY_FILE%" -Dcatalina.base="%CATALINA_BASE%" -Dcatalina.home="%CATALINA_HOME%" -Djava.io.tmpdir="%CATALINA_TMPDIR%" %MAINCLASS% %CMD_LINE_ARGS% %ACTION%
  338. goto end
  340. :end

打赏

                    支付宝                                                         微信

微信与支付宝支付

添加新批注
在作者公开此批注前，只有你和作者可见。
回复批注